golden hour

/opt/cpanel/perl5/536/site_lib/Perl/Critic/Policy/Variables

File/Folder	Size	Actions
ProhibitAugmentedAssignmentInDeclaration.pm	4.06 KB
ProhibitConditionalDeclarations.pm	2.8 KB
ProhibitEvilVariables.pm	13.17 KB
ProhibitLocalVars.pm	3.5 KB
ProhibitMatchVars.pm	3.37 KB
ProhibitPackageVars.pm	6.65 KB
ProhibitPerl4PackageNames.pm	3.01 KB
ProhibitPunctuationVars.pm	14.68 KB
ProhibitReusedNames.pm	5.33 KB
ProhibitUnusedVariables.pm	5.16 KB
ProtectPrivateVars.pm	2.34 KB
RequireInitializationForLocalVars.pm	2.92 KB
RequireLexicalLoopIterators.pm	4.28 KB
RequireLocalizedPunctuationVars.pm	5.41 KB
RequireNegativeIndices.pm	6.87 KB

Edit: ProhibitUnusedVariables.pm

package Perl::Critic::Policy::Variables::ProhibitUnusedVariables;

use 5.010001;
use strict;
use warnings;

use Readonly;
use List::SomeUtils qw( any );

use PPI::Token::Symbol;
use PPIx::QuoteLike;

use Perl::Critic::Utils qw< :characters :severities >;
use parent 'Perl::Critic::Policy';

our $VERSION = '1.152';

#-----------------------------------------------------------------------------

Readonly::Scalar my $EXPL =>
    q<Unused variables clutter code and make it harder to read>;

#-----------------------------------------------------------------------------

sub supported_parameters { return ()                     }
sub default_severity     { return $SEVERITY_MEDIUM       }
sub default_themes       { return qw< core maintenance certrec > }
sub applies_to           { return qw< PPI::Document >    }

#-----------------------------------------------------------------------------

sub violates {
    my ( $self, $elem, $document ) = @_;

my %symbol_usage;
    _get_symbol_usage( \%symbol_usage, $document );
    _get_regexp_symbol_usage( \%symbol_usage, $document );
    return if not %symbol_usage;

my $declarations = $document->find('PPI::Statement::Variable');
    return if not $declarations;

my @violations;

DECLARATION:
    foreach my $declaration ( @{$declarations} ) {
        next DECLARATION if 'my' ne $declaration->type();

my @children = $declaration->schildren();
        next DECLARATION if any { $_->content() eq q<=> } @children;

VARIABLE:
        foreach my $variable ( $declaration->variables() ) {
            my $count = $symbol_usage{ $variable };
            next VARIABLE if not $count; # BUG!
            next VARIABLE if $count > 1;

push
                @violations,
                $self->violation(
                    qq<"$variable" is declared but not used.>,
                    $EXPL,
                    $declaration,
                );
        }
    }

return @violations;
}

sub _get_symbol_usage {
    my ( $symbol_usage, $document ) = @_;

my $symbols = $document->find('PPI::Token::Symbol');
    return if not $symbols;

foreach my $symbol ( @{$symbols} ) {
        $symbol_usage->{ $symbol->symbol() }++;
    }

foreach my $class ( qw{
        PPI::Token::Quote::Double
        PPI::Token::Quote::Interpolate
        PPI::Token::QuoteLike::Backtick
        PPI::Token::QuoteLike::Command
        PPI::Token::QuoteLike::Readline
        PPI::Token::HereDoc
        } ) {
        foreach my $double_quotish (
            @{ $document->find( $class ) || [] }
        ) {
            my $str = PPIx::QuoteLike->new( $double_quotish )
                or next;
            foreach my $var ( $str->variables() ) {
                $symbol_usage->{ $var }++;
            }
        }
    }

return;
}

sub _get_regexp_symbol_usage {
    my ( $symbol_usage, $document ) = @_;

foreach my $class ( qw{
        PPI::Token::Regexp::Match
        PPI::Token::Regexp::Substitute
        PPI::Token::QuoteLike::Regexp
        } ) {

foreach my $regex ( @{ $document->find( $class ) || [] } ) {

my $ppix = $document->ppix_regexp_from_element( $regex ) or next;
            $ppix->failures() and next;

foreach my $code ( @{
                $ppix->find( 'PPIx::Regexp::Token::Code' ) || [] } ) {
                my $subdoc = $code->ppi() or next;
                _get_symbol_usage( $symbol_usage, $subdoc );
            }

}

return;
}

#-----------------------------------------------------------------------------

__END__

#-----------------------------------------------------------------------------

=pod

=head1 NAME

Perl::Critic::Policy::Variables::ProhibitUnusedVariables - Don't ask for storage you don't need.

=head1 AFFILIATION

This Policy is part of the core L<Perl::Critic|Perl::Critic>
distribution.

=head1 DESCRIPTION

Unused variables clutter code and require the reader to do mental
bookkeeping to figure out if the variable is actually used or not.

At present, this Policy is very limited in order to ensure that there
aren't any false positives.  Hopefully, this will become more
sophisticated soon.

Right now, this only looks for simply declared, uninitialized lexical
variables.

my $x;          # not ok, assuming no other appearances.
    my @y = ();     # ok, not handled yet.
    our $z;         # ok, global.
    local $w;       # ok, global.

This module is very dumb: it does no scoping detection, i.e. if the
same variable name is used in two different locations, even if they
aren't the same variable, this Policy won't complain.

Have to start somewhere.

=head1 CONFIGURATION

This Policy is not configurable except for the standard options.

=head1 AUTHOR

Elliot Shank C<< <perl@galumph.com> >>

=head1 COPYRIGHT

This program is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.  The full text of this license
can be found in the LICENSE file included with this module.

=cut

# Local Variables:
#   mode: cperl
#   cperl-indent-level: 4
#   fill-column: 78
#   indent-tabs-mode: nil
#   c-indentation-style: bsd
# End:
# ex: set ts=8 sts=4 sw=4 tw=78 ft=perl expandtab shiftround :